dnl Run `aclocal' to create macro file (if missing).
dnl Run `automake -a -c' to copy macro files (if missing).
dnl Run `autoconf' to create `configure' script.

AC_INIT(src/sidtune.cpp)
AC_CONFIG_AUX_DIR(scripts)
AM_INIT_AUTOMAKE(libsidplay, 1.36.47)
LIBVERSION=1
AC_SUBST(LIBVERSION)dnl libtool-style version

dnl AM_CONFIG_HEADER(src/config.h)dnl not required

AC_CANONICAL_HOST
AC_PREFIX_DEFAULT(/usr)

AC_PROG_CXX
AC_LANG_CPLUSPLUS

dnl Check whether the compiler has bool.
SID_CHECK_BOOL

dnl Check for nothrow allocator.
SID_CHECK_EXCEPTIONS

dnl Check whether ios::binary is ios::bin.
SID_CHECK_IOS_BIN

AC_C_BIGENDIAN
if test $ac_cv_c_bigendian = yes; then
    SID_SUBST(SID_WORDS_ENDIANESS,SID_WORDS_BIGENDIAN)
else
    SID_SUBST(SID_WORDS_ENDIANESS,SID_WORDS_LITTLEENDIAN)
fi  
  
AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(short int)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(long int)

dnl SID_SUBST(SID_SIZEOF_CHAR,$ac_cv_sizeof_char)
dnl SID_SUBST(SID_SIZEOF_SHORT_INT,$ac_cv_sizeof_short_int)
dnl SID_SUBST(SID_SIZEOF_INT,$ac_cv_sizeof_int)
dnl SID_SUBST(SID_SIZEOF_LONG_INT,$ac_cv_sizeof_long_int)

if test $ac_cv_sizeof_long_int -lt 4; then
  AC_MSG_ERROR([platform unsupported: sizeof(long int) < 4]);
fi

AC_HEADER_STDC

AC_CHECK_FUNC(strncasecmp,[SID_SUBST_DEF(SID_HAVE_STRNCASECMP)],
    [SID_SUBST_UNDEF(SID_HAVE_STRNCASECMP)])
AC_CHECK_FUNC(strcasecmp,[SID_SUBST_DEF(SID_HAVE_STRCASECMP)],
    [SID_SUBST_UNDEF(SID_HAVE_STRCASECMP)])

AC_CHECK_HEADER(strstrea.h,[SID_SUBST_DEF(SID_HAVE_STRSTREA_H)],
    [SID_SUBST_UNDEF(SID_HAVE_STRSTREA_H)])

dnl AC_CHECK_HEADER(strstrea.h,[AC_DEFINE(SID_HAVE_STRSTREA_H)],[])

AC_SYS_LONG_FILE_NAMES
if test $ac_cv_sys_long_file_names = yes; then
    SID_SUBST_DEF(SID_HAVE_LONG_FILE_NAMES)
else
    SID_SUBST_UNDEF(SID_HAVE_LONG_FILE_NAMES)
fi

dnl Initialize libtool.
dnl AM_DISABLE_STATIC
SID_PROG_LIBTOOL
AC_SUBST(CXXFLAGS)

AC_OUTPUT(Makefile src/compconf.h src/libcfg.h src/Makefile)